
    ExIcon

Generic icon library for Phoenix LiveView.
	Downloads icon sets and generates Phoenix LiveView function components.
	Generates components from a folder of your own SVG files.
	Extensible via behaviour to support multiple icon libraries.
	Icon library versions are set via configuration. Update your icons without
updating this library.
	Generate components for all icons or only the ones you need.
	Customize the component attributes, or accept the global HTML attributes.
	Dev-only dependency. The library is only used for generating icon modules.

Installation
Add ex_icon to your list of dependencies in mix.exs:
def deps do
  [
    {:ex_icon, "~> 1.0.0", only: :dev}
  ]
end
Usage
ExIcon expects a configuration file named .ex_icon.exs in your project root.
[
  icon_sets: [
    lucide: [
      # A module implementing the `ExIcon.Provider` behaviour.
      provider: ExIcon.Providers.Lucide,
      # The release version of the icon library.
      version: "1.8.0",
      # The destination path of the icon module that ExIcon will generate.
      module_path: "lib/my_app_web/components/lucide.ex",
      # The name of the generated module.
      module_name: MyAppWeb.Components.Lucide,
      # If supported by the provider, choose the style variants to generate
      # Example: [:outline, :solid]
      variants: [],
      # SVG attributes to turn into component attributes, to override, or to
      # add. Example: ["stroke", {"stroke-width", default: "1.5"}]
      attrs: [],
      # Whether the components accept the global HTML attributes. Can be a
      # boolean or a keyword list with options to pass to `attr`.
      global_attrs: false,
      # Either list only the icons you want to generate, or set to `:all` to
      # generate all available icons.
      icons: ["arrow-left", "arrow-right"],
      # Icon names to skip, which is mostly useful with `icons: :all`.
      exclude: []
    ]
  ]
]
lucide is a name of your choice. It labels the icon set in the output of the
task and enables you to selectively build it with
mix ex_icon.gen.icons --icon-set lucide. You can configure any number of icon
providers. See ExIcon.options/0 for all available options.
With your configuration in place, you can download the configured releases and
generate a module with function components for every icon set with:
mix ex_icon.gen.icons

Downloaded releases are cached in your Mix cache folder (~/.cache/mix/ex_icon
on Linux, ~/Library/Caches/mix/ex_icon on macOS), so regenerating your icons
does not download the same release again. The exact path is printed after the
task ran.
Paths in the configuration file stay relative to the folder you run the task in.
Run mix help ex_icon.gen.icons for the available command line arguments.
Icon names
Each function component is named after its SVG file in snake case, so
arrow-left.svg becomes arrow_left. Names that start with a digit get an
icon_ prefix, since HEEx does not accept component names that start with a
digit. 1password.svg becomes icon_1password. Names that are reserved words
in Elixir get the same prefix, so end.svg becomes icon_end.
Icons with names that cannot be turned into function names are skipped and
reported. If you listed such an icon in your configuration, the task fails
instead.
Icon contents
ExIcon only keeps the SVG elements and attributes it knows. If an icon uses
anything else, such as a script element or an onclick attribute, ExIcon
skips the icon and prints the reason. If you listed such an icon in your
configuration, the task fails instead.
Attributes that load another document are not allowed. href, xlink:href, and
url() references in clip-path, color, fill, mask, stop-color and
stroke may only point at an ID in the same file. A style attribute may only
use known CSS functions, and may not contain a backslash.
ExIcon removes metadata elements and elements with a namespace prefix other
than svg. Such elements are commonly added by editors like Inkscape.
Attributes
ExIcon can optionally turn SVG attributes into function component attributes,
override the values of the original SVG files, and add attributes that the
original SVG files do not have.
For example, consider this original SVG:
<svg
  xmlns="http://www.w3.org/2000/svg"
  width="24"
  height="24"
  viewBox="0 0 24 24"
  stroke="currentColor"
  stroke-width="2"
  stroke-linecap="round"
>
  <path d="m12 19-7-7 7-7" />
  <path d="M19 12H5" />
</svg>
And this configuration:
attrs: [
  # component attribute, defaults to the value in the SVG file
  "stroke",

  # component attribute with a default value that overrides the value in the
  # SVG file
  {"stroke-width", default: "1.5"},

  # component attribute with a limited set of values
  {"stroke-linecap", values: ["square", "round"]},

  # required attribute
  {"class", required: true},

  # optional component attribute that is omitted unless it is passed
  {"stroke-dasharray", default: nil},

  # sets a fixed attribute value without adding a component attribute
  {"fill", fixed: "none"}
]
The generated function component will look like this:
attr :stroke, :string, default: "currentColor"
attr :stroke_width, :string, default: "1.5"
attr :stroke_linecap, :string, values: ["square", "round"], default: "round"
attr :class, :string, required: true
attr :stroke_dasharray, :string, default: nil

def arrow_left(assigns) do
  ~H"""
  <svg
    xmlns="http://www.w3.org/2000/svg"
    width="24"
    height="24"
    viewBox="0 0 24 24"
    stroke={@stroke}
    stroke-width={@stroke_width}
    stroke-linecap={@stroke_linecap}
    class={@class}
    stroke-dasharray={@stroke_dasharray}
    fill="none"
    aria-hidden="true"
  >
    <path d="m12 19-7-7 7-7" />
    <path d="M19 12H5" />
  </svg>
  """
end
Note that if you generate a lot of icons, compilation times can increase
substantially by adding component attributes.
Global attributes
Generated components only accept the attributes you configure. Set
global_attrs to also accept the global HTML attributes, such as id,
class, phx-click and data-*:
global_attrs: true
Instead of true, you can pass the default and include options of attr:
global_attrs: [default: %{"class" => "size-6"}, include: ["fill"]]
ExIcon writes the attributes you pass to a component before the ones of the SVG
file, so that yours take precedence. Both end up in the markup, and HTML keeps
the first of the two. <Lucide.arrow_left width="48" /> therefore renders with
a width of 48, even if the icon has one.
Variants
Some icon libraries ship the same icons in multiple styles. For example,
Heroicons has outlined and filled icons in several sizes. Select the ones you
need with the variants option:
heroicons: [
  provider: ExIcon.Providers.Heroicons,
  version: "2.2.0",
  module_path: "lib/my_app_web/components/heroicons.ex",
  module_name: MyAppWeb.Components.Heroicons,
  variants: [:outline, :solid],
  attrs: ["stroke", "stroke-width", "fill"],
  icons: ["academic-cap", "bell"]
]
Each variant is generated into a separate module, with the variant appended to
module_name and module_path. In this example, ExIcon generates
MyAppWeb.Components.Heroicons.Outline into
lib/my_app_web/components/heroicons/outline.ex and
MyAppWeb.Components.Heroicons.Solid into
lib/my_app_web/components/heroicons/solid.ex. No module is written to the
configured module_path itself.
Without the option, ExIcon generates a single module from the variant that the
provider falls back to, which is :outline for Heroicons.
Local icon sets
You can also generate an icon module from a local folder with SVG files by using
the path option instead of provider and version:
custom: [
  path: "assets/icons",
  module_path: "lib/my_app_web/components/custom.ex",
  module_name: MyAppWeb.Components.Custom,
  icons: :all
]
The variants option is not supported for local folders.
Providers
Providers for specific icon libraries are based on the ExIcon.Provider
behaviour. The library currently supports these providers:
	Heroicons
	Lucide
	Simple Icons

You can write a provider for any icon library that publishes its releases as a
zip file. A provider tells ExIcon where to download a release, and where the
SVG files are in it.
defmodule MyApp.Feather do
  @behaviour ExIcon.Provider

  @impl true
  def release_url(version) do
    "https://github.com/feathericons/feather/archive/refs/tags/v#{version}.zip"
  end

  @impl true
  def svg_folder(version), do: "feather-#{version}/icons"
end
You can configure the module like any other provider in your configuration file:
feather: [
  provider: MyApp.Feather,
  version: "4.29.2",
  module_path: "lib/my_app_web/components/feather.ex",
  module_name: MyAppWeb.Components.Feather,
  icons: :all
]
For a library that ships the same icons in several styles, implement the
optional ExIcon.Provider.variants/1 callback, which returns the folder of
each style. ExIcon.Providers.Heroicons is an example.
Versioning
ExIcon follows semantic versioning. The public API is:
	the format of the configuration file
	the ExIcon.Provider behaviour
	the command line interface of mix ex_icon.gen.icons
	the shape of the generated components: one function component per icon, named
after the SVG file in snake case, with a :string attribute for every
attribute configured with attrs

Everything else is internal, including all functions of the ExIcon module. The
generated modules only depend on Phoenix.Component, so upgrading ExIcon never
requires regenerating them.
Project status
ExIcon is actively maintained, but since it covers the use cases it was built
for, you may not see frequent releases. Issues are fixed, and providers for
further icon libraries are added when the need arises. There may well be use
cases that ExIcon does not cover yet.
Contributing
Please open an issue or PR if you need additional options, features, or support
for other icon libraries. Be sure to read the contributing guidelines.


  

    Changelog

All notable changes to this project are documented in this file.
The format is based on Keep a Changelog,
and this project adheres to
Semantic Versioning.
Unreleased
1.0.0 - 2026-08-29
Stable release.
0.6.0 - 2026-08-15
Changed
	Use Mix.raise/1 for exceptions.
	Increase TLS depth to 3.

Fixed
	Use canonical casing for SVG element and attribute names.
	Validate module_name in configuration.
	Report the path and the line of the configuration file when it does not
parse.
	Name the missing callback when a module configured as provider does not
implement the ExIcon.Provider behaviour.

0.5.0 - 2026-08-02
Fixed
	Check the generated module before formatting it, so that an icon which does
not produce valid code is reported instead of raising in the formatter.
	Turn a CRLF and a lone CR in an icon into a LF, as XML requires.
	Add an icon_ prefix to a generated function name that is a reserved word in
Elixir, so that end.svg becomes icon_end instead of generating a module
that does not compile.

Security
	Refuse release archives with entries that would be written outside the target
folder.
	Check the name a zip entry carries in its local file header, not only the one
in the central directory.
	Refuse a release archive whose entries cannot be listed, instead of unpacking
it unchecked.
	Only allow known CSS functions in a style value, and reject values that
contain a backslash.
	Only allow clip-path, color, fill, mask, stop-color and stroke
values that point into the same file.
	Hold a character written into an icon to the same rule as a reference to it,
which was only applied to references before.
	Reject control characters and invisible characters such as a bidirectional
override.

0.4.0 - 2026-08-01
Added
	Add default, values, required, and fixed options to attribute
configuration, which allows you more control over the attributes in the
generated HEEx components.
	Add optional ExIcon.Provider.variants/1 callback and variants
configuration option for icon libraries that have multiple style variants.
Each variant is generated into a module of its own, from a single download.
	Add provider for Heroicons, which has outlined and filled variants in
several sizes.
	Add --cache-dir, --config, --force, and --refresh arguments to
mix ex_icon.gen.icons. See mix help ex_icon.gen.icons.
	Add exclude configuration option to skip individual icons.
	Add path configuration option to generate an icon set from a local folder.
	Add global_attrs configuration option to accept global HTML attributes
in the generated components.

Changed
	Skip icons that use SVG elements or attributes that ExIcon does not know,
which prevents scripts and event handlers from being added to generated
components. Remove metadata elements and elements with a namespace prefix
other than svg.
	Only allow href and xlink:href values that point at an ID in the same
file. Reject style values that contain url().
	The handling of whitespaces and character references such as &#233; was
changed. Regenerating your icon modules with this version may produce diffs
even though the source SVG files haven't changed.
	Cache downloaded releases in the Mix cache folder instead of downloading them
into a shared temporary folder on every run.
	Only move a release into the cache once it is complete, so that an
interrupted run does not leave a partial release behind.
	Add connect and receive timeouts to the release download.
	Fail if a module was not written.
	Fail if an icon listed in the configuration was not generated.
	Check the provider and the variants of every icon set before downloading or
writing anything.
	Nest the icon sets in the configuration file under an icon_sets key.
	Rename ExIcon.Lucide and ExIcon.SimpleIcons to ExIcon.Providers.Lucide
and ExIcon.Providers.SimpleIcons.

Removed
	Remove ExIcon.transform_svg/2.

Fixed
	Keep the aria-hidden value set by an SVG file instead of always overwriting
it with true.
	Apply configured attributes to SVG files that have no attributes at all.
	Ignore folders with an .svg extension when generating all icons of a
release.
	Do not ask to overwrite generated modules that have not changed.
	Format all generated modules instead of only the first one.
	Keep attributes that are written with single quotes, and namespaced attribute
names such as xmlns:xlink, which used to end up as xlink.
	Add an icon_ prefix to generated function names that start with a digit, so
that icons: :all works for Simple Icons.
	Raise if two icons map to the same function name.

Security
	Escape SVG attribute values in the generated module. Previously, an attribute
value containing #{} was written into the generated component code
unescaped, where it would be evaluated during compilation.
	Skip icons whose names cannot be turned into function names. Previously, a
file name in a release was written into the generated module unchecked, where
it could add arbitrary code.
	Validate version string before downloading.
	Set modes of the unpacked files instead of taking them from the archive.
	Refuse a release archive that unpacks to more than 250 MB.
	Require an https URL from a provider, unless it points at the local machine.
	Parse icon files instead of copying their contents into the generated module.
Previously, an icon file could end the heredoc of a component and add code to
the module, or add a HEEx expression that was evaluated every time the
component was rendered.

How to upgrade
Move the icon sets in your configuration under an icon_sets key, and rename
the bundled providers:
 [
-  lucide: [
-    provider: ExIcon.Lucide,
-    # ...
-  ]
+  icon_sets: [
+    lucide: [
+      provider: ExIcon.Providers.Lucide,
+      # ...
+    ]
+  ]
 ]
0.3.0 - 2026-04-10
Added
	Add provider for Simple Icons.
	Add --icon-set flag to mix ex_icon.gen.icons.

Changed
	Change c:ExIcon.Provider.svg_folder/0 to ExIcon.Provider.svg_folder/1,
with the argument being the version.

0.2.0 - 2026-04-10
Changed
	Replace ignore_attrs option with attrs.
	Add aria-hidden="true" to SVGs if not already present.

0.1.2 - 2026-04-10
Fixed
	Run mix format separately instead of relying on copy_template/4 for
formatting to ensure formatter config is applied.

0.1.1 - 2026-04-10
Fixed
	Add Mix template to release.

0.1.0 - 2026-04-10
Initial release.

Refer to the readme for usage instructions.
All functions of this module are internal. They are only used by
mix ex_icon.gen.icons.

        options()

      


        The options that every icon set in .ex_icon.exs takes.

          @type options() :: [
  icons: [binary()] | term(),
  exclude: [binary()],
  provider: atom(),
  version: binary(),
  path: binary(),
  module_path: binary(),
  module_name: term(),
  variants: [atom()],
  global_attrs: boolean() | keyword(),
  attrs: term()
]


      


The options that every icon set in .ex_icon.exs takes.
	:icons - Required. Either a list of icon names you want to generate (e.g. ["arrow-left"]),
or :all if you want to generate all available icons.

	:exclude (list of String.t/0) - Icon names to skip, which is mostly useful in combination with
icons: :all. Example: ["1password"]. The default value is [].

	:provider (atom/0) - A module implementing the ExIcon.Provider behaviour. Required with
version, unless path is set.

	:version (String.t/0) - The release version of the icon library.

	:path (String.t/0) - Path to a folder that contains SVG files. Cannot be used together with
provider and version.

	:module_path (String.t/0) - Required. The destination path of the icon module that ExIcon will generate
for you. Example: "lib/my_app_web/components/lucide.ex".

	:module_name (module/0) - Required. The name of the generated module. Example: MyApp.Components.Lucide.

	:variants (list of atom/0) - The variants of the icon library to generate, for providers that
implement ExIcon.Provider.variants/1. Example: [:outline, :solid].
Each variant is generated into a separate module, with the variant
appended to module_name and module_path.
Example:
	module_name: MyApp.Components.Heroicons
	module_path: "lib/my_app_web/components/heroicons.ex"
	generated module name for the :outline variant:
MyApp.Components.Heroicons.Outline
	path of the module for the :outline variant:
lib/my_app_web/components/heroicons/outline.ex

Defaults to an empty list, which generates a single module from
ExIcon.Provider.svg_folder/1.
Not supported if path is set.
The default value is [].

	:global_attrs - Adds an attr :rest, :global to the generated components, so that they
accept the global HTML attributes, such as id, class, phx-click and
data-*.
Set to true, or to a keyword list with the default and include
options of attr. Example:
[default: %{"class" => "size-6"}, include: ["fill"]].
The attributes that are passed to a component are written before the ones
of the SVG file, so that they take precedence.
The default value is false.

	:attrs (list of String.t/0 or {t:String.t/0, keyword}) - Configures the attributes of the <svg> element. Each entry is either an
attribute name, or a tuple with the attribute name and options.
If a list entry is a string (e.g. "stroke"), the value is replaced with
a HEEx variable and a component attribute is added.
If a list entry is a tuple, the following options are supported:
	default ({"stroke-width", default: "1.5"}) - Sets the default
option on attr.
	values ({"stroke-linecap", values: ["square", "round"]}) - Sets the
values option on attr. Generation fails if the value in an SVG file
is not among the values.
	required ({"stroke-width", required: true}) - Sets the required
option on attr.
	fixed ({"fill", fixed: "none"}) - Sets a fixed value for the
SVG attribute without adding a component attribute.

Attributes that are not present in the original SVG file are added, as
long as a :default, :fixed, :values or :required is given.
Attribute names are matched case-insensitively, and each attribute may
only be configured once.
If an attribute is added but neither the SVG file nor :default provides
a value, required: true is added to the component attribute.
An aria-hidden attribute is always added, and can be configured like
any other attribute. Without configuration, the value of the SVG file is
kept, or "true" is used if it does not have the attribute.
The default value is [].

Behaviour for icon providers.

    Callbacks
  


    
      
        release_url(version)

      


        Returns the download URL for the release with the given version.



    


    
      
        svg_folder(version)

      


        Returns the folder that contains the SVG files in the unpacked release.



    


    
      
        variants(version)

      


        Returns the folder of each variant of the icon library.

          @callback release_url(version) :: url when version: String.t(), url: String.t()


      


Returns the download URL for the release with the given version.
The URL must point to a zip file, and must use https unless it points at the
local machine. Only this URL is checked: the HTTP client follows redirects,
which may lead to another host or to plain http.

          @callback svg_folder(version) :: String.t() when version: String.t()


      


Returns the folder that contains the SVG files in the unpacked release.
For a provider with variants, this is the folder of the variant to use when
the configuration does not select any.

  



  
    
      
    
    
      variants(version)

          @callback variants(version) :: %{required(atom()) => Path.t()} when version: String.t()


      


Returns the folder of each variant of the icon library.
Some icon libraries ship the same icons in multiple styles, such as outlined
and filled. Providers for such libraries implement this callback, which allows
the variants configuration option to select them. Each variant is generated
into a module of its own.
This callback is optional. Without it, the library has a single variant, and
the variants option cannot be used.
Example
def variants(version) do
  %{
    outline: "heroicons-#{version}/optimized/24/outline",
    solid: "heroicons-#{version}/optimized/24/solid"
  }
end

ExIcon provider for Heroicons.
https://heroicons.com
The library has four variants, which can be selected with the variants
configuration option:
	:outline - outlined icons on a 24x24 viewbox
	:solid - filled icons on a 24x24 viewbox
	:mini - filled icons on a 20x20 viewbox
	:micro - filled icons on a 16x16 viewbox

Without the option, only the :outline variant is generated.
Note that the variants differ in their attributes. The outlined icons have
stroke and stroke-width attributes and a fill of none, while the
filled ones only have a fill of currentColor. Attributes that a variant
does not have are ignored, so a single attrs option can cover all of them.
Not every icon is available in every variant.

ExIcon provider for Lucide icons.
https://lucide.dev

      




  

    
ExIcon.Providers.SimpleIcons 
    



      
ExIcon provider for Simple Icons.
https://simpleicons.org

Downloads the configured icon libraries and generates the icon modules.
$ mix ex_icon.gen.icons

For every icon set in the configuration file, a module with a function
component per icon is generated. An icon set either names a provider and a
version, in which case the release of the icon library is downloaded, or a
folder that already holds the SVG files.
Releases are cached, so regenerating the icons does not download them again.
Paths in the configuration file are relative to the folder the task is run in.
Command line options
	--cache-dir - the folder to cache the downloaded releases in, defaults
to the Mix cache folder
	--config - the path of the configuration file, defaults to
.ex_icon.exs in the folder the task is run in
	--force - overwrites the generated modules without asking
	--icon-set - only generates the given icon set, which must be one of
the keys under icon_sets in the configuration file
	--refresh - discards the cached releases and downloads them again

The task fails if a module was not written, so that a pipeline that
regenerates the icons does not pass with modules that are out of date. Pass
--force to write them without being asked.
Examples
Generate all configured icon sets:
$ mix ex_icon.gen.icons

Generate a single icon set and download its release again:
$ mix ex_icon.gen.icons --icon-set lucide --refresh

Regenerate the icons in a pipeline:
$ mix ex_icon.gen.icons --force

Read the configuration from a different path:
$ mix ex_icon.gen.icons --config config/icons.exs

